DD2DMS

=DD2DMS(range)
range
range with GPS coordinates in decimal degrees
DD2DMS converts GPS coordinates from Decimal Degrees to Degrees Minutes Seconds
lrobbo314

lrobbo314

Well-known Member
Joined
Jul 14, 2008
Messages
3,929
Office Version
  1. 365
Platform
  1. Windows
DD2DMS converts GPS coordinates from Decimal Degrees to Degrees Minutes Seconds

Excel Formula: 
=LAMBDA(range,
    MAP(range,
        LAMBDA(x,
            TEXTJOIN(", ",,
                MAP(TEXTSPLIT(SUBSTITUTE(x," ",""),,","),
                    LAMBDA(c,
                        LET(
                            deg,INT(c),
                            min,INT((c-deg)*60),
                            sec,ROUND((c-deg-min/60)*3600,3),
                            deg&"° "&min&"' "&sec&CHAR(34)
                        )
                    )
                )
            )
        )
    )
)

GPS
ABC
2Decimal Degree InputDD2DMS
332.1142145,-114.2514532° 6' 51.172", -115° 44' 54.78"
432.554842,-112.5488432° 33' 17.431", -113° 27' 4.176"
Data
Cell Formulas
RangeFormula
C3:C4C3=DD2DMS(A3:A4)
Dynamic array formulas.
 
Upvote 0
Noticed an error with this function. This should be correct.

Excel Formula: 
=LAMBDA(range,
    MAP(range,
        LAMBDA(x,
            TEXTJOIN(",",,
                MAP(TEXTSPLIT(SUBSTITUTE(x," ",""),,","),
                    LAMBDA(c,
                        LET(
                            a,abs(c),
                            deg,INT(a),
                            min,INT((a-deg)*60),
                            sec,ROUND((a-deg-min/60)*3600,3),
                            if(value(c)<0,"-","") & deg&"° "&min&"' "&sec&CHAR(34)
                        )
                    )
                )
            )
        )
    )
)
 
You must log in or register to reply here.

Forum statistics

Threads
1,216,503
Messages
6,131,022
Members
449,616
Latest member
PsychoCube

Share this page

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Back
Top